[Jaroslav's] camera didn’t have a feature to measure the speed of its response in different modes so he figured out his own method. Using the microphone on his webcam he recorded the sound made by the mirror and shutter movements, then used Audacity to analyze the camera’s performance.

When you get right down to it, this is a fantastic idea. Audacity, the open source audio editing suite, has the ability to show each captured audio track next to each other. That makes it easy for you to precisely align the clips, and has in-build time measuring features with fantastic resolution.

He tested a whole bunch of different settings on a Canon EOS600D DSLR camera. In the image above you can see him comparing performance between different ISO settings. He also looks into different brands and sizes of SD storage cards, as well as the time difference when storing raw image data versus JPEG encoded data.

In our hands-on review of the Digilent chipKIT Uno32, we posed the question of what the lasting appeal might be for a 32-bit Arduino work-alike. We felt it needed some novel applications exploiting its special features…not just the same old Arduino sketches with MOAR BITS. After the fractal demo, we’ve hit upon something unique and fun…

So just what are the chipKIT’s unique features over a stock Arduino? Until the expected Ethernet shield ships this summer, a few ideas are on hold. Let’s see then…there’s no shortage of MIPS, of course…but there’s also heaps of RAM and flash storage. And with the latter, sampled audio came to mind. There are Arduino shields for just this sort of thing — the Adafruit Wave Shield turns up in many projects, using an SD card for sound storage — but if one’s needs are modest, the chipKIT’s PIC32 is perfectly capable of storing brief audio samples in its own flash program space, no cards, adapters or added expense required. We estimate the Max32 can hold nearly a full minute of voice-quality audio.

Playing with the idea, we found we could do one better. Actually, several better. A limitation of SD card-based players like the Wave Shield is that they can only play one sound at a time. Dealing with the FAT filesystem and buffering audio data off the card takes nearly everything the Arduino’s little ATmega chip can muster…polyphonic sound requires kludges. But our flash-resident audio samples on the chipKIT are trivial to access. With the fast 32-bit CPU, many samples can be processed simultaneously…and then, with gobs of RAM, time-based effects such as reverb can be added. And before we knew it, there was a toy synthesizer sitting on the table:

Having previously dabbled with the PIC32 using Microchip’s tools, we were surprised by the simplicity with which this went together. A few early rough spots aside, the chipKIT and MPIDE environment show major promise for being every bit as simple as Arduino. In fact, the whole build was completed faster than the documentation phase. And then a second surprise, even to us: everything in the parts list, aside from the chipKIT board itself, is common stuff that could be found at RadioShack. No funky special ICs, components or mail-order shields. Most of the “magic” is in software, thanks to this fast microcontroller.

Here’s a demonstration of the finished mini-synth in action:

Please excuse the demonstrator’s tragic lack of rhythm and coordination. This is why professional musicians get paid millions while amateurs lead sad lives as technology bloggers. Be thankful that we spared you the blooper reel.

Input is via five piezoelectric transducers (RadioShack #273-0073, $2.19 each) attached to analog inputs A0 through A4. We could have just used pushbuttons, sure, but we wanted something that could sense the pressure of each hit, and these were cheaper than force-sensitive resistors. Piezo sensors have a specific polarity, and the positive side (red wires) should connect to the analog inputs, and black to ground. There’s also a 2000 Ohm resistor added across each element:

Input for the reverb effect is straightforward. Two 10K potentiometers on analog inputs A6 and A7 (these are on the second row of analog inputs on the chipKIT Uno32, not present on Arduino). One controls the amplitude, the other controls the delay:

Finally, sound output uses high-speed PWM output on digital pin 3, passed through a simple low-pass filter to a headphone jack:

On our breadboard we’re using a handy little headphone breakout board from SparkFun, but one could just solder the appropriate wire leads onto a bare jack from “The Shack” (ugh). You may want to optionally add a 1 Meg pot just before the headphone jack. The circuit worked fine as-is with headphones or an amplified iPod speaker, but totally saturated our camera’s microphone input when fed directly.

This demo uses 16 KHz sound samples. As per Nyquist theory, the low-pass filter is then designed for an 8 KHz (-ish) cutoff frequency. For purely voice applications, half those rates should be sufficient (saving flash space and allowing longer samples), and the two resistor values should then be doubled.

And that’s it for parts. Can you believe it? On to the code…

To begin, we need something that can convert sound files into a format the C compiler can use. An ugly little UNIX command-line utility converts WAV files from a very specific format (8-bit mono, uncompressed) into C header files that can be #included by the MPIDE project. Arduino normally would use the PROGMEM directive to put these tables into the code flash space, but that’s not required here. Surprisingly, the much-loved Audacity program wouldn’t export 8-bit WAVs, but we found it possible to batch convert sounds using iTunes.

const signed char sample_drum[] = {
        0x02,0x03,0x01,0x00,0x00,0x00,0x00,0x01,
        0x01,0x01,0x01,0x01,0x01,0x01,0x01,0x00,
        ...HUNDREDS OF LINES OF STUFF...
        0xff,0xff,0xff,0xfd,0xfd,0xff,0x00,0x00,
        0x00,0x00,0x00,0x00,0x02,0x00 };

We’ll spare you the horror of looking at that code or doing the conversion. You can download the complete set of project files here, and then adapt it to your own needs. The remainder of this article deals only with the MPIDE code.

But first, one fix is required: in our prior article, we encountered an issue with the chipKIT’s analog read speed, and a fix was discussed in the comments. This involves scrounging among the MPIDE source files for “wiring_analog.c” and changing a few lines. The old code resembles:

delayMicroseconds(99);
while ( ! mAD1GetIntFlag() ) { }
analogValue = ReadADC10(0);
mAD1ClearIntFlag();

This should be changed to:

delayMicroseconds(2);
mAD1ClearIntFlag();
while ( ! mAD1GetIntFlag() ) { }
analogValue = ReadADC10(0);

We’re told this change will be incorporated into later releases of the toolkit and this won’t be necessary for much longer. If you’re just ripping out the digital audio code from this project and ignoring this drum pad stuff, you can skip the change altogether.

And then there’s our sketch code:

// Mini sampling synthesizer for chipKIT Uno32.

#include "sounds.h"       // N_SAMPLES and data are here
#define PWM_PIN         3 // OC1 PWM output - don't change
#define SAMPLE_RATE 16000 // All samples fixed at 16 KHz
#define MAX_SOUNDS     10 // Polyphonic limit
#define MAX_ECHO     4000 // 1/4 sec fits in Uno32 RAM

short
  echo_data[MAX_ECHO]; // Circular buffer for echo

int
  echo_delay = 0, // Duration of echo effect
  echo_vol   = 0, // Echo effect volume (0-1023)
  echo_pos   = 0; // Current position in echo buffer
volatile int      // May change during interrupt:
  n_sounds   = 0; // Number of sounds currently playing

struct soundStruct {
  int sample; // Index of corresponding audio sample
  int pos;    // Current position within sample
  int vol;    // Playback volume, 0-1023
} sound[MAX_SOUNDS];

#define N_PADS N_SAMPLES // One pad for each sample

struct padStruct {
  short max;       // Max pressure during press (0-1023)
  short count;     // Timer for filtering out noise
  byte  triggered; // If set, currently reading a press
  short add;       // If >0, begin sound at next interrupt
} pad[N_PADS];

void setup()
{
  memset(pad, 0, sizeof(pad));    // Clear drum pad data
  memset(echo_data, 0, sizeof(echo_data)); // Clear echo
  pinMode(PWM_PIN, OUTPUT);     // Enable PWM output pin

  // Open Timer2, 1:1 w/256 tick interval (for 8-bit PWM)
  OpenTimer2(T2_ON | T2_PS_1_1,256);
  OpenOC1(OC_ON | OC_TIMER2_SRC | OC_PWM_FAULT_PIN_DISABLE,
    0,0);

  // Open Timer1 with interrupt for sample mixer (16 KHz)
  ConfigIntTimer1(T1_INT_ON | T1_INT_PRIOR_3);
  OpenTimer1(T1_ON | T1_PS_1_1, F_CPU / SAMPLE_RATE);

  delay(1);  // Slight delay avoids false trigger at start.
}

// Piezo transducers as input pads are fussy.
// To avoid false positives, a bit of hysteresis is used:
#define PRESS_MIN     20 // Must read at least this force
#define PRESS_COUNT    3 // for this many samples, then...
#define RELEASE_MAX    8 // Must read less than this force
#define RELEASE_COUNT 15 // for this many samples.
// Still imperfect; there are occasional double-triggerings
// and false triggers on adjacent pads.  Could be addressed
// with better mounting and isolation of pads and/or with
// improved input filtering in code or in hardware.

// The loop() function just reads pad and dial inputs; all
// audio work is done in the subsequent interrupt function.

void loop()
{
  int i, a;

  for(i = 0; i < N_PADS; i++) {  // Sample each pad...
    a = analogRead(i);

    if(pad[i].triggered) {    // Previously pressed?
      if(a <= RELEASE_MAX) {  // Yes, released now?
        if(++pad[i].count >= RELEASE_COUNT) {  // Really?
          // Sounds aren't added to play list here, just
          // flagged; they're added to the mix in the
          // interrupt.  This avoids a race condition
          // where this code may be trying to add a sound
          // while the interrupt is removing one.
          pad[i].add       = pad[i].max;
          pad[i].triggered = 0;
          pad[i].count     = 0;
        }
      } else {  // Still pressed...watch for new max
        if(a > pad[i].max) pad[i].max = a;
        pad[i].count = 0;  // Reset release counter
      }
    } else if(a >= PRESS_MIN) {  // Untriggered; new press?
      if(++pad[i].count >= PRESS_COUNT) {  // Really?
        pad[i].triggered = 1; // Flag to watch for release
        pad[i].count     = 0;
        pad[i].max       = a;
      }
    } else {  // Untriggered and below press threshold
      pad[i].count = 0;  // Clear press counter
    }
  }

  // Echo parameters come from potentiometers on A6 and A7
  echo_vol   = analogRead(6);
  echo_delay = map(analogRead(7), 0, 1023, 0, MAX_ECHO);
}

// This is the mixing/sample-playing interrupt,
// invoked at 16 KHz to match the audio sample rate.
// With guidance from Mark Sproul's PIC32 port of
// Brett Hagman's Tone library for Arduino.
extern "C"
{

void __ISR(_TIMER_1_VECTOR,ipl3) playSample(void)
{
  int i = 0, sum = 0;

  mT1ClearIntFlag();  // Clear interrupt flag

  while(i < n_sounds) {  // For each sound playing...
    // Waveform is cumulative, NOT averaged
    sum += (int)sample[sound[i].sample].data[sound[i].pos] *
      sound[i].vol;
    sound[i].pos++;  // Advance counter.  If end hit...
    if(sound[i].pos >= sample[sound[i].sample].size) {
      n_sounds--;  // Decrement number of sounds playing:
      // Move sound at end of list to the slot currently
      // occupied by the vacating sound (unless the same)
      if(i < n_sounds) {
        memcpy(&sound[i], &sound[n_sounds],
          sizeof(soundStruct));
        continue;  // Sound moved; dont advance index
      }
    }
    i++;
  }
  sum /= 1024;

  // Add in echo effect (if enabled) from circular buffer.
  // This takes place before audio level clipping so that
  // any clipping distortion won't be repeated in echo.
  if((echo_delay > 0) && (echo_vol > 0)) {
    sum += echo_data[echo_pos] * (echo_vol + 1) / 1024;
    echo_data[echo_pos] = sum;
    if(++echo_pos >= echo_delay) echo_pos = 0;
  }

  // Clip audio to 8-bit range.  This may cause distortion
  // when multiple sounds or echo exceed the 8-bit range.
  // Invoking the "quick & dirty" alibi again.
  if(sum < -128)     sum = -128;
  else if(sum > 127) sum =  127;

  SetDCOC1PWM(sum + 128);  // Set PWM output value 0-255

  // Check for any new sounds flagged by loop().
  // Done last because sounds finished above will
  // free up polyphonic slots.
  for(i = 0; i < N_PADS; i++) {
    if(pad[i].add) {
      if(n_sounds < MAX_SOUNDS) {
        sound[n_sounds].sample = i;
        sound[n_sounds].pos    = 0;
        sound[n_sounds].vol    = pad[i].add + 1;
        n_sounds++;
      }
      pad[i].add = 0;  // Clear flag even if not added
    }
  }
}

} // end extern "C"

Explanation:

The setup() function initializes two timers:

• Timer 2 and Output Compare 1 (hardware features of the PIC32 chip) are used for pulse width modulation (PWM). In conjunction with the filter previously described, this positions the speaker for each audio sample (Google for “PWM DAC” for explanations and examples). The PWM input clock is set to the chip’s full speed of 80 MHz, with an interval of 256 “ticks” (for 8-bit resolution), yielding a PWM waveform at 312,500 Hz. For this sort of DAC filtering it’s recommended that the PWM frequency be at least ten times the sample rate, so this is more than adequate for our needs. This is also why the code bypasses the native Arduino analogWrite() function for PWM, which operates on a much slower clock. Lastly, using Output Compare 1 dictates that we must use digital pin 3 for the audio output; this is one of the five native hardware PWM lines on this chip.
• Timer 1 operates at our audio sample frequency (16 KHz) and has an interrupt function attached. This function mixes audio samples and changes the PWM duty cycle of Timer2/OC1. The rates on both of these timers are set up once and never need to change, just the one duty cycle is varied.

This section of the code (and one line in the interrupt function) is admittedly not very Arduino-like, directly accessing hardware features in a non-portable manner. A more formal implementation would abstract these details into a library to which the novice programmer could just pass data. But for the sake of a simple, single-file demo, there it is, warts and all. In many ways, this is just a starting point to work from.

The loop() function reads the state of the piezo sensors and marks sounds to be played (received by the interrupt, later). There’s some crude debouncing of the piezo inputs…this really could use some more sophisticated filtering (which the PIC32 could easily handle), but it was skipped for brevity. The code generally detects varying pressure, but there’s still a fair bit of false triggering going on. In this function the reverb controls are also read: just two analogRead() calls, with the second one then mapped to the full length of the reverb buffer.

The interrupt handler is where all the fun stuff happens, and it’s surprisingly simple.

The extern “C” declaration makes the C++ compiler happy with the interrupt function declaration.

The program is designed for up to ten concurrent sounds, the details of which are held in the “sound” structure array (there’s more than enough CPU performance for greater polyphony, but it’s mostly just a matter that the input pads aren’t terribly practical for this). When a pad hit is sensed, a new item is added to this array (up to the maximum). Structure elements indicate which audio sample is used for this sound, the current playback position within the sample, and the volume level.

Audio samples are stored as signed values (rather than unsigned) because this makes them easier to mix (just add together) and easier to adjust gains (just multiply). Every opportunity is taken to use fixed-point math. From the prior fractal demo, we saw what a massive performance difference this can make — sometimes orders of magnitude. Most of our analog readings (returned as 10 bit integers from 0 to 1023) correspond to a gain (relative volume) value of 0.0 to 1.0 (or 0% to 100%). To perform this scaling in fixed-point units, add 1 to the reading, perform the multiplication (one instruction on the PIC32), then divide by 1024 (a simple shift operation, also one instruction). There’s no loss in accuracy vs. converting to floating-point; the source and destination values are going to be quantized anyway.

// Floating-point, slow:
// scale = float 0.0 to 1.0
out = (int)((float)in * scale);

// Fixed-point, crazy fast:
// scale = integer 0 to 1023
out = in * (scale + 1) / 1024;

Along these lines, note that where the audio samples are summed, this division is skipped until the end. This saves some cycles and the result works out the same. Algebraically speaking, (A/X)+(B/X)=(A+B)/X, and so forth. The interim 32-bit sum isn’t likely to overflow.

Fixed-point math happens again when applying reverb. The echo volume, in the integer variable echo_vol (10 bit again, from one of the analog knobs) is in the range 0 to 1023, corresponding to 0% (no reverb) to 100% (echo is as loud as the original sound). Reverb (in echo_data[] array) is a circular buffer — as sounds are played, the contents here (scaled by echo_vol) are first added to the output, then the result is placed back in the same position in the array and the position counter is incremented by one. When the end of the array is reached (or a shorter limit indicated by echo_delay) we “wrap around” back to the beginning.

The final resulting audio value is clipped to an 8-bit range. This may introduce clipping distortion when many loud sounds are used simultaneously. For brevity again, bells and whistles have been omitted, but courageous programmers could opt to add “soft clipping” here to limit such distortion. There’s ample CPU muscle.

The final 8-bit signed value is then transposed into the unsigned range and fed into the OC1 duty cycle for PWM output.

Lastly, the interrupt checks for any sounds that the loop() function flagged as being “hit,” and adds these to the concurrent play list. This flag-and-add behavior, rather than adding items directly in loop(), avoids a potentially nasty race condition whereby loop() could be in the midst of adding a sound just as the interrupt is removing others, throwing off the counter.

And that’s all there is to it. This demo only uses about one fourth of the storage on the Uno32, which itself has one fourth the capacity of the Max32…and we’ve yet to exploit any sort of compression. There could be some fun applications here, maybe adding better Super Mario sounds to toilets or voice prompts to other chipKIT projects (“Your door is ajar”). What other ideas could you see happening here?

It’s that time again, time to take on the machine with the Hackerspace, Crash Space (and part two)! The team of Californians set out and successfully turned the front of their building into a musical instrument, similar to [David Byrne's] Playing the Building. When a pedestrian walks by they set off distance sensors, which in turn actuate mallets that strike particular objects to produce a tone. We were pleasantly surprised at how interactive the installation was, even if it didn’t sound that great. But will it be enough to beat out the previous two teams? And how will it do up against Artisans Asylum’s not what you’re thinking Breakfast Machine next time?

[thanks Deven]

Because the Arduino is in such high demand for producing multiple musical tones at the same time; [Jeremy Blum] has successfully figured out the math and other necessaries that will take your once previously single tone producing MCU and turn it into a 5 tone producing machine. unsurprisingly its really just some creative use of PWM control but it all works out in the end anyway and helps prevent you from purchasing additional sound generating chips. This truly does open up some new doors, as [Jeremy] shows with his still in production thingamakit like project: ReacXion.

[MicroMinded] took us way back to our childhoods with his experiments and subsequent YMstream music player based on the Yamaha YM2149 sound generator used in old arcade systems, computers, and even phones (think chiptune). This reminds us of the Chipophone, only this time the sound is achieved from ICs used back in the day, rather than MCU waveforms.

There is still some work to be done to make the music player have a bit more functionality, but for now source is available if you want to make your own. Of course you might come across a small problem; finding an SSG is a tad bit more difficult than say, an Arduino. If a good resource is found, please share it in the comments!

[Thank you Andrew Kretschmer for sending in the chiptune mp3s]

While we could be content following our “kiddie d-day” as [Caleb Kraft] suggested. We know you can’t continue such an awesome Friday without trying to blow yourself up first.

This Wiimote Rubens’ tube caught our eye. A PVC Aluminum irrigation pipe is drilled with holes and propane is pumped through. A speaker on one end creates changes in pressure and a neat light show follows suit. [ScaryBunnyMan] went further though, with a collection of software and a Wii Remote he “plays god” controlling the music, and thus, the fire. Check out a fun video after the split.

[Via Make]

This is (video above) perhaps the most abstract way of playing sounds…ever. Yes, we’ve heard Hard Drive music and Obsolete technology bands, but [DJ Sures] brings us the first ever, spark plug instrument.

Much like Velcro and Teflon, the musical spark plug is claimed to be an accident. After testing energy use vs. spark power with his flare stack ignition controller, [DJ Sures] noticed that different frequencies could be produced. It was only a matter of reprogramming before death metal Twinkle Twinkle Little Star is heard. Now he just needs to refine it a bit and build a full stereo cabinet.

Finally a guitar that all of the arcade gaming geeks can jam with. [Mike Davenport] sent us his 8bit arcade based guitar for his senior project. Details are a little sparse if you intend to build you own at the moment, but he does mention the basics: such as it uses an FPGA for logic and function, the strings and joystick modify pitch, it has selectable waves and other parameters, and even includes save banks! Check out a video of him playing street fighter rocking out after the break.

[Drew] wrote a library for playing multichannel music on an Arduino. The project connects multiple piezo buzzers to the popular prototyping platform and handles the dirty work involved in modulating multiple buzzers at the same time. The video above starts with an explanation for the first three minutes but if you’re impatient you can jump directly to the music demonstration. The results are magnificent. We’re going to check out the code and see what we can make happen just as soon as we can round-up multiple piezos.

[Ryan] let us know about his Max/MSP Controller. Inside the device is an ADXL 335 accelerometer and 6 push buttons wired to an Arduino. The input data is sent to Max MSP, a sequencer controlling 5 audio tracks, correlating to 5 of the buttons. The 6th button controls delay. What we really liked was how the accelerometer modified the speed of the beat in the X-axis, and the delay intensity with the Y-axis. Whats next? We think gesture recognition might be something fun to try, but [Ryan] is unsure. We’ll keep you up to date.

Popped balloons or bullets fired into apples, anyone can photograph with a quick sound based camera rig. Lasers have been used forever in motion detection. And even door bell chimes have been used before for remote camera shutter releases. No, [SaskView] wanted to go further and created his Laser Triggered High-Speed Photography setup, to photograph (of all things) milk splashes. We liked the simplicity of the project however;  requiring no programmed microchips or overly complicated circuitry – rather he took a quick trip to the local dollar shop, used the amazing CHDK firmware, and he produced perfect results every time.

[Update: CHDK, not CHKD firmware. My mind must be elsewhere. Thanks jbot and agent smith]

This past weekend, Berlin played host to Music Hack Day – an event where attendants built and tested hacks, contraptions, and software all dealing with sound, music, or the distribution thereof. Some of the hacks are simply mind blowing to see built in only a day or two. Like the location based CitySounds.fm or Tracks on a Map – mapping out where your music is from. Or the music based games and composition tools, iLoveAcid squencer and MaschineFighter – adding some crazy fun to MIDI.

Oh, we almost forgot, we can’t go an entire post without mentioning something Arduino; named Xylobot – a set of servos powered by Arduino, tapping out rhythm on a xylophone (video above). Another Hack Day is planned so keep an eye out.

[Thanks robb]

German designer [Michael Schoner] of NL Architects turned an ordinary street bench into a public sound system that can be accessed by passersby with iPods and cellphones with Bluetooth. Boom Bench features 60 watt co-axial speakers, two subwoofers, and a bass shaker in the seat that’ll allow you to feel the vibrations of your music choices. It was on display in Amsterdam last month for the Urban Play event. It remains to be seen whether this new urban development will make your daily wait for the bus more entertaining or aggravating.

[via Notcot]

One of his projects is called the Finger Player: it is a record player needle worn on the finger somewhat like a thimble, making the act of playing records into a tactile experience.

Another project is the Prepared Turntable, which is a player with five tone arms that have independent faders and volume controls. We feel this project has a great deal of potential in genuine music production, not just as a novelty.

[Suzuki]‘s most compelling work is completely off the turntable. Dubbed the Sound Chaser, it is some thing like a toy train running on a small track, except this train has a record needle and the tracks are made from records that have been cut into train track-like segments. The sounds played by the Sound Chaser can be modified by swapping segments of the vinyl track out, mixing and matching for an endless variety of possible songs. We’ll be keeping our eye on [Suzuki]; his ideas seem so basic yet so fresh. If you’ll be in London before July 5, be sure to check out his work at the RCA.

You can make pretty much anything a speaker by vibrating it. Japanese engineer, [Keiji Koga], has been working for many years to perfect his plant based sound transmission system. The voice coil is at the bottom of the plant container and transfers sound up the stalk to the leaves. It’s and interesting idea, but we can’t imagine it sounds much better than vibrating a rigid surface.

[via io9]